1．無(wú)開(kāi)關(guān)

無(wú)開(kāi)關(guān)的for語(yǔ)句能夠?qū)υO(shè)定的范圍內(nèi)進(jìn)行循環(huán)，是最基本的for循環(huán)語(yǔ)句。其命令格式為：

FOR %%variable IN (set) DO command

其中，%%variable是批處理程序里面的書(shū)寫(xiě)格式，在DOS中書(shū)寫(xiě)為%variable，即只有一個(gè)百分號(hào)(%)；set就是需要我們?cè)O(shè)定的循環(huán)范圍，類(lèi)似于C語(yǔ)言里面的循環(huán)變量；do后面的command就是循環(huán)所執(zhí)行的命令，即循環(huán)體。

無(wú)開(kāi)關(guān)for語(yǔ)句舉例：

===============================================

@echo off

for %%i in (a,"b c",d) do echo %%i

pause>nul

===============================================

2．開(kāi)關(guān)/L

含開(kāi)關(guān)/L的for語(yǔ)句，可以根據(jù)set里面的設(shè)置進(jìn)行循環(huán)，從而實(shí)現(xiàn)對(duì)循環(huán)次數(shù)的直接控制。其命令格式為：

FOR /L %%variable IN (start,step,end) DO command

其中，start為開(kāi)始計(jì)數(shù)的初始值，step為每次遞增的值，end為結(jié)束值。當(dāng)end小于start時(shí)，step需要設(shè)置為負(fù)數(shù)。

含開(kāi)關(guān)/L的for語(yǔ)句舉例(創(chuàng)建5個(gè)文件夾)：

===============================================

@echo off

for /l %%i in (1,2,10) do md %%i

pause

===============================================

上例將新建5個(gè)文件夾，文件夾名稱(chēng)依次為1．3．5．7．9。可以發(fā)現(xiàn)，%%i的結(jié)束值并非end的值10，而是不大于end的一個(gè)數(shù)。

3．開(kāi)關(guān)/F

含開(kāi)關(guān)/F的for語(yǔ)句具有最強(qiáng)大的功能，它能夠?qū)ψ址M(jìn)行操作，也能夠?qū)γ畹姆祷刂颠M(jìn)行操作，還可以訪問(wèn)硬盤(pán)上的ASCII碼文件，比如txt文檔等。其命令格式為：

FOR /F ["options"] %%variable IN (set) DO command

其中，set為("string"、'command'、file-set)中的一個(gè)；options是(eol=c、skip=n、delims=xxx、tokens=x,y,m-n、usebackq)中的一個(gè)或多個(gè)的組合。各選項(xiàng)的意義參見(jiàn)for /f。一般情況下，使用較多的是skip、tokens、delims三個(gè)選項(xiàng)。

含開(kāi)關(guān)/F的for語(yǔ)句舉例：

===============================================

@echo off

echo **No Options:

for /f %%a in ("1,2,10") do echo a=%%a

echo **Options tokens ^& delims:

for /f "tokens=1-3 delims=," %%a in ("1,2,10") do echo a=%%a b=%%b c=%%c

pause

===============================================

@echo off

echo 本文件夾里面的文件有：

for /f "skip=5 tokens=3* delims= " %%a in ('dir') do (

if not "%%a"=="<DIR>" if not "%%b"=="字節(jié)" if not "%%b"=="可用字節(jié)" echo %%b

)

pause

===============================================

@echo off

echo 本文件夾里面的文件有：

dir>c:\file.txt

for /f "skip=5 tokens=3* delims= " %%a in (c:\file.txt) do (

if not "%%a"=="<DIR>" if not "%%b"=="字節(jié)" if not "%%b"=="可用字節(jié)" echo %%b

)

del c:\file.txt

pause

===============================================

對(duì)于后面的兩個(gè)例子，其中options里面的delims= 是可以刪除的，因?yàn)橹灰砑恿?F開(kāi)關(guān)系統(tǒng)就將delims的值默認(rèn)為空格。

符號(hào)字符串中的最后一個(gè)字符星號(hào)，

那么額外的變量將在最后一個(gè)符號(hào)解析之后

分配并接受行的保留文本。本例中也可以改為4，不過(guò)文件名中有空格的文件，只能顯示空格以前部分

同時(shí)我們也看到了，for語(yǔ)句的do后面的command也是可以分行的，只需要保證command的左括號(hào)和do在同一行就可以了。

4．開(kāi)關(guān)/D或/R

含開(kāi)關(guān)/D或/R的for語(yǔ)句是與目錄或文件有關(guān)的命令，一般情況下很少使用。含開(kāi)關(guān)/R的命令有時(shí)候被用于通過(guò)遍歷文件夾來(lái)查找某一個(gè)文件或文件夾，故而列舉此例。

含開(kāi)關(guān)/R的for語(yǔ)句舉例(文件夾遍歷)：

===============================================

@echo off

setlocal enabledelayedexpansion

FOR /R d: %%i IN (.) DO (

set dd=%%i

set "dd=!dd:~0,-1!"

echo !dd!

)

pause

exit

===============================================

上例即可以羅列出D盤(pán)下的所有文件夾，其速度要比命令"tree d:"慢多了，不過(guò)其返回結(jié)果的實(shí)用性則遠(yuǎn)遠(yuǎn)超過(guò)了tree命令。

一般情況下我們不推薦通過(guò)遍歷文件夾來(lái)查找文件，特別是在查找某些程序(比如 QQ.exe)的位置時(shí)。推薦通過(guò)reg命令查找注冊(cè)表來(lái)查找QQ的路徑，以保證查找效率。

上例中也出現(xiàn)了幾個(gè)新面孔，如setlocal、感嘆號(hào)等。其中，感嘆號(hào)其實(shí)就是變量百分號(hào)(%)的強(qiáng)化版。之所以要用!而不用%，是因?yàn)樵趂or循環(huán)中，當(dāng)一個(gè)變量被多次賦值時(shí)，%dd%所獲取的僅僅是dd第一次被賦予的值；要想刷新dd的值，就必須首先通過(guò)命令"setlocal enabledelayedexpansion"來(lái)開(kāi)啟延遲變量開(kāi)關(guān)，然后用!dd!來(lái)獲取dd的值。

for語(yǔ)句是批處理里面功能最強(qiáng)大、使用最普遍卻又最難掌握的一套命令，這也是批處理菜鳥(niǎo)和批處理高手最明顯的一個(gè)分水嶺，一旦掌握了這套命令，那么你就離批處理達(dá)人不遠(yuǎn)了！

參考： http://www.cnblogs.com/yang-hao/p/6002869.html